home *** CD-ROM | disk | FTP | other *** search
/ Mac Magazin/MacEasy 32 / Mac Magazin and MacEasy Magazine CD - Issue 32.iso / Grafik & Text / OzTeX3.0 / Metafont / Inputs / ec / exillett.mf < prev    next >
Text File  |  1997-03-16  |  22KB  |  572 lines
  1. % exillett.mf
  2. %
  3. % (c) Copyright 1995, 1996, 1997 J"org Knappen
  4. % (c) Copyright 1990, 1992 Norbert Schwarz
  5. %
  6. % This file is part of ecfonts version 1.0
  7. %
  8. % Please read the files 00readme.txt, 00inst.txt, 00error.txt, and
  9. % copyrite.txt for further information
  10. %
  11. % You find some documentation in ecdoc.tex (needs LaTeX2e)
  12. %
  13. % Content:
  14. %
  15. %   lowercase italic letters a to z
  16.  
  17. version_check(1,0);  % |version_check| was introduced in dc1.3
  18.  
  19. ecchar "Italic letter a";
  20. beginchar("a",9u#,x_height#,0);
  21. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  22. adjust_fit(0,0); pickup fine.nib;
  23. pos0(hair,0); pos1(vair,90); pos2(curve,180); pos3(vair,270);
  24. pos4(stem,0); x4=x0; y4+.5stem=vround .98h;
  25. x1=x3=.5[x0,x2]; lft x2r=hround(1.5u-.5curve);
  26. rt x4r=hround(w-2.5u+.5stem);
  27. top y1r=h+oo; bot y3r=-oo; y0=y2=.5[y1,y3];
  28. filldraw stroke super_arc.e(0,1) & pulled_arc.e(1,2)
  29.  & pulled_arc.e(2,3) & super_arc.e(3,0);  % bowl
  30. x5=x4; x7=w; hook_out(5,6,7);  % closing hook
  31. filldraw circ_stroke z4e--z5e;  % stem
  32. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  33. penlabels(0,1,2,3,4,5,6,7); endchar;
  34.  
  35. ecchar "Italic letter b";
  36. beginchar("b",8u#,asc_height#,0);
  37. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  38. adjust_fit(0,0); pickup tiny.nib;
  39. pos1(stem,0); pos2(stem,0); x1=x2;
  40. lft x1l=hround(1.5u-.5stem); top y1=h; y2=.5x_height;
  41. filldraw stroke z1e--z2e;  % stem
  42. sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % serif
  43. pickup fine.nib; pos2'(stem,-180); pos3(vair,-90);
  44. pos4(curve,0); pos5(vair,90); pos0(hair,180);
  45. z0=z2=z2'; x3=x5=.5[x2,x4]; rt x4r=hround(w-1.5u+.5curve);
  46. bot y3r=-oo; top y5r=x_height+oo; y4=y2;
  47. filldraw stroke pulled_arc.e(2',3) & pulled_arc.e(3,4)
  48.  & pulled_arc.e(4,5) & super_arc.e(5,0);  % bowl
  49. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  50. penlabels(0,1,2,3,4,5); endchar;
  51.  
  52. ecchar "Italic letter c";
  53. beginchar("c",8u#,x_height#,0);
  54. italcorr if math_fitting:1/3x_height#*slant else:x_height#*slant-u# fi;
  55. adjust_fit(0,0); pickup fine.nib;
  56. pos0(flare,0); pos1(hair,0); pos2(vair,90);
  57. pos3(curve,180); pos4(vair,270); pos5(hair,320);
  58. x2=x4=.5(w+u); rt x1r=max(rt x2,hround(w-u))+eps;
  59. lft x3r=hround(1.5u-.5curve); x5r=good.x(w-eps); x6=x5;
  60. y1=.5[bar_height,h]; top y2r=h+oo; bulb(2,1,0);  % bulb
  61. bot y4r=-oo; y3=.5[y2,y4]; top y5l=vround .5bar_height; y6=bar_height;
  62. path p; p=z4{right}..z5..z6;
  63. filldraw stroke pulled_arc.e(2,3)
  64.  & pulled_arc.e(3,4)...{direction 1 of p}z5e;  % arc
  65. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  66. penlabels(0,1,2,3,4,5,6); endchar;
  67.  
  68. ecchar "Italic letter d";
  69. beginchar("d",9u#,asc_height#,0);
  70. italcorr max(1/3x_height#*slant+.5hair#+.5u#,
  71.   h#*slant+.5stem#-2u#) if math_fitting:-.5u# fi;
  72. adjust_fit(0,0); pickup fine.nib;
  73. pos0(hair,0); pos1(vair,90); pos2(curve,180); pos3(vair,270);
  74. x0=x4; x1=x3=.5[x0,x2]; lft x2r=hround(1.5u-.5curve);
  75. x4+.5stem=hround(w-2.5u+.5stem);
  76. top y1r=x_height+oo; bot y3r=-oo; y0=y2=.5[y1,y3];
  77. filldraw stroke super_arc.e(0,1) & pulled_arc.e(1,2)
  78.  & pulled_arc.e(2,3) & super_arc.e(3,0);  % bowl
  79. x5=x0; x7=w; hook_out(5,6,7);  % closing hook
  80. pickup tiny.nib; pos5'(stem,0); pos4(stem,0);
  81. z5'=z5; top y4=h; filldraw stroke z4e--z5'e;  % stem
  82. sloped_serif.l(4,5',a,1/3,jut,serif_drop);  % serif
  83. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  84. penlabels(0,1,2,3,4,5,6,7); endchar;
  85.  
  86. ecchar "Italic letter e";
  87. beginchar("e",8u#,x_height#,0);
  88. italcorr max(1/3x_height#*slant,x_height#*slant+.5(.2[hair#,stem#])-u#);
  89. adjust_fit(0,0); pickup fine.nib;
  90. pos0(vair,-90); pos1(heavy_hair,0); pos2(vair,90);
  91. pos3(curve,180); pos4(vair,270); pos5(hair,320);
  92. x0=rt x3l; rt x1r=hround(w-1.5u+.5heavy_hair); x2=x4=.5(w+u);
  93. lft x3r=hround(1.5u-.5curve); x5r=good.x(w-eps); x6=x5;
  94. y0=y3=y6=bar_height; y1=.5[y0,y2]; top y2r=h+oo; bot y4r=-oo;
  95. top y5l=vround .5bar_height; path p; p=z4{right}..z5..z6;
  96. filldraw stroke z0e{right}...z1e{up}...pulled_arc.e(2,3)
  97.  & pulled_arc.e(3,4)...{direction 1 of p}z5e;  % arc
  98. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  99. penlabels(0,1,2,3,4,5,6); endchar;
  100.  
  101. ecchar "Italic letter f";
  102. beginchar("f",max(1.5u#,stem#)+max(3.5u#,2flare#),asc_height#,desc_depth#);
  103. italcorr asc_height#*slant+.75u#;
  104. adjust_fit(if monospace:u#,u# else: 0,0 fi); pickup fine.nib;
  105. numeric theta; z88=(.5w-.5u,h); z89=(.5w+.5u,-d); theta=angle(z88-z89);
  106. pos0(flare,0); pos1(hair,0); pos2(vair,90);
  107. pos3(.5[hair,stem],180); pos4(stem,theta+90);
  108. pos5(stem,theta-90); pos6(.5[hair,stem],0);
  109. pos7(vair,-90); pos8(hair,-180); pos9(flare,-180);
  110. rt x1r=hround(w+.25u); lft x8r=hround-.35u; x2=.6[x1,x4]; x7=.6[x8,x5];
  111. y9-.5flare=vround -.85d; y2-y0=y9-y7; top y2r=h+oo; bot y7r=-d-oo;
  112. y4=.25[x_height,h]; y5=.5[-d,y4];
  113. z4=whatever[z88,z89]; z5=whatever[z88,z89];
  114. x3=.8[x2+x4-x88,x88]; x6=.8[x7+x5-x89,x89]; y3=.8[y4,y2]; y6=.8[y5,y7];
  115. bulb(2,1,0); bulb(7,8,9);  % bulbs
  116. filldraw stroke z2e{left}...z3e...{z89-z88}z4e;  % upper arc
  117. filldraw z4r--z5l--z5r--z4l--cycle;  % stem
  118. filldraw stroke z5e{z89-z88}...z6e...{left}z7e;  % lower arc
  119. pickup crisp.nib; pos20(bar,90); pos21(bar,90);
  120. top y20r=top y21r=x_height;
  121. lft x20=lft x4r-.5stem-u; rt x21=rt x4l+.5stem+1.5u;
  122. filldraw stroke z20e--z21e;  %  crossbar
  123. math_fit(desc_depth#*slant+u#,x_height#*slant);
  124. penlabels(0,1,2,3,4,5,6,7,8,9,20,21,88,89); endchar;
  125.  
  126. ecchar "Italic letter g";
  127. beginchar("g",8u#,x_height#,desc_depth#);
  128. italcorr x_height#*slant+.5stem#-u#;
  129. adjust_fit(0,0); pickup fine.nib;
  130. pos0(hair,0); pos1(vair,90); pos2(curve,180); pos3(vair,270);
  131. x0=x4; x1=x3=.5[x0,x2]; lft x2r=hround(1.5u-.5curve);
  132. x4+.5stem=hround(w-1.5u+.5stem);
  133. top y1r=h+oo; bot y3r=0; y0=y2=.5[y1,y3];
  134. filldraw stroke super_arc.e(0,1) & pulled_arc.e(1,2)
  135.  & pulled_arc.e(2,3) & super_arc.e(3,0);  % bowl
  136. pos4(stem,0); y4+.5stem=vround .98h;
  137. pos5(stem,0); x5=x4; y5=-1/3d;
  138. pos6(vair,-90); pos7(hair,-180); pos8(flare,-180);
  139. bot y6r=-d-oo; y8-.5flare=vround -.9d;
  140. lft x8r=hround(2u-.5flare); x6=x1; bulb(6,7,8);  % bulb
  141. filldraw circ_stroke z4e---z5e...{left}z6e;  % stem and arc
  142. math_fit(-min(.3x_height#*slant+.5curve#-u#,1.5u#-desc_depth#*slant),
  143.  ic#-1/3x_height#*slant); penlabels(0,1,2,3,4,5,6,7,8); endchar;
  144.  
  145. ecchar "Italic letter h";
  146. beginchar("h",9u#,asc_height#,0);
  147. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  148. adjust_fit(0,0); pickup tiny.nib;
  149. pos1(stem,0); pos2(stem,0); x1=x2;
  150. lft x1l=hround(1.5u-.5stem); top y1=h; y2-.5stem=-oo;
  151. filldraw circ_stroke z2e--z1e;  % left stem
  152. sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % serif
  153. pickup fine.nib; x4+.5stem=hround(w-2.5u+.5stem);
  154. x5=x4-.25u; ital_arch(2,3,4);  % arch
  155. x7=w; hook_out(5,6,7)(skewed);  % closing hook
  156. filldraw stroke z4e{down}..{-u,-x_height}z5e;  % right stem
  157. math_fit(0,ic#); penlabels(1,2,3,4,5,6,7); endchar;
  158.  
  159. ecchar "Italic letter i";
  160. beginchar("i",5u#,min(asc_height#,10/7x_height#+.5flare#),0);
  161. italcorr max(1/3x_height#*slant+.5hair#+.5u#,h#*slant+.5flare#-2u#);
  162. adjust_fit(if monospace:u#,u# else: 0,0 fi); pickup fine.nib;
  163. x0=0; x5=w; x2=.5w+.25u; x3=.5w-.25u;
  164. if classic_serif:
  165.   hook_out(3,4,5)(skewed);  % hooks
  166.   top y2=x_height;
  167.   pos2(stem,0);
  168.   sloped_serif.l(2,3,a,1/3,jut,serif_drop);
  169. else:
  170.   hook_in(0,1,2)(skewed);
  171.   hook_out(3,4,5)(skewed);  % hooks
  172. fi
  173. filldraw stroke z2e--z3e;  % stem
  174. pos8(flare,0); pos9(flare,90);
  175. x8=.5w if not monospace:-.4(h-x_height)*slant fi; top y9r=h+1;
  176. if classic_serif: else:
  177.  if bot y9l-top y1<slab: y9l:=min(y9r-eps,y1+fine+slab); fi
  178. fi
  179. x8=x9; y8=.5[y9l,y9r]; dot(8,9);  % dot
  180. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  181. penlabels(0,1,2,3,4,5,8,9); endchar;
  182.  
  183. ecchar "Italic letter j";
  184. beginchar("j",5u#,min(asc_height#,10/7x_height#+.5flare#),desc_depth#);
  185. italcorr h#*slant+.5stem#-u#;
  186. adjust_fit(if monospace:2u#,.5u# else: 0,0 fi); pickup fine.nib;
  187. x0=0; x2=x3; pos3(stem,0); lft x3l=hround(w-1.5u-.5stem);
  188. if classic_serif:
  189.   pos4(vair,-90); pos5(hair,-180); pos6(flare,-180);
  190.   bot y3=-1/3d; bot y4r=-d-oo; y6-.5flare=-vround.9d;
  191.   top y2=x_height;
  192.   pos2(stem,0);
  193.   sloped_serif.l(2,3,a,1/3,jut,serif_drop);
  194. else:
  195.   hook_in(0,1,2);  % opening hook
  196.   pos4(vair,-90); pos5(hair,-180); pos6(flare,-180);
  197.   bot y3=-1/3d; bot y4r=-d-oo; y6-.5flare=-vround.9d;
  198. fi
  199. x4=1/3(w-u); lft x5r=min(hround-.5u,lft x5r+x4-x5l-eps);
  200. filldraw stroke z2e---z3e...{left}z4e;  % stem and arc
  201. bulb(4,5,6);  % bulb
  202. pos8(flare,0); pos9(flare,90);
  203. rt x8r=rt x2r if not monospace:-.6(h-x_height)*slant fi; top y9r=h+1;
  204. if classic_serif: else:
  205.    if bot y9l-top y1<slab: y9l:=min(y9r-eps,y1+fine+slab); fi
  206. fi
  207. x8=x9; y8=.5[y9l,y9r]; dot(8,9);  % dot
  208. math_fit(desc_depth#*slant,x_height#*slant+.5stem#-u#);
  209. penlabels(0,1,2,3,4,5,6,8,9); endchar;
  210.  
  211. ecchar "Italic letter k";
  212. beginchar("k",8u#,asc_height#,0);
  213. italcorr x_height#*slant;
  214. adjust_fit(0,0); pickup tiny.nib;
  215. pos1(stem,0); pos2(stem,0); x1=x2;
  216. lft x1l=hround(1.5u-.5stem); top y1=h; y2-.5stem=-oo;
  217. filldraw circ_stroke z2e--z1e;  % left stem
  218. sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % serif
  219. pickup fine.nib; pos3(vair,90); x3=x1; y3=bar_height;
  220. pos4(vair,90); x4=w-2u; top y4r=x_height+oo;
  221. filldraw stroke z3e{right}..{right}z4e;  % upper diagonal
  222. pos5(hair,0); pos6(flare,0);
  223. rt x5r=hround(w-.5u); y5+.5flare=vround(bot y4l-.03x_height);
  224. bulb(4,5,6);  % bulb
  225. pos7(stem,0); pos8(vair,90); pos9(hair,180);
  226. x9+.5hair=hround(w+.5hair-eps); y9=1/3x_height;
  227. lft x7l=hround(w-2.75u-.5stem); y7=1/2y3; x8=w-1.2u; bot y8l=-oo;
  228. filldraw stroke z3e{right}...z7e{down}
  229.  ...z8e{right}...{up}z9e;  % lower diagonal
  230. math_fit(0,1/3x_height#*slant+.5hair#+.5u#);
  231. penlabels(1,2,3,4,5,6,7,8,9); endchar;
  232.  
  233. ecchar "Italic letter l";
  234. beginchar("l",4u#,asc_height#,0); l_width#:=4u#;
  235. italcorr max(1/3x_height#*slant+.5hair#+.5u#,
  236.  asc_height#*slant+.5stem#-2u#) if math_fitting:+.5u# fi;
  237. adjust_fit(if monospace:u#,u# else: 0,0 fi); pickup fine.nib;
  238. x2-.5stem=hround(1.5u-.5stem); x4=w; hook_out(2,3,4);  % closing hook
  239. pickup tiny.nib; pos1(stem,0); pos2'(stem,0); z2'=z2;
  240. top y1=h; x1=x2; filldraw stroke z1e--z2'e;  % stem
  241. sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % serif
  242. math_fit(-.5u#,1/3x_height#*slant+.5hair#+u#); penlabels(1,2,3,4); endchar;
  243.  
  244. ecchar "Italic letter m";
  245. beginchar("m",15u#,x_height#,0);
  246. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  247. adjust_fit(if monospace:-1.5u#,-2u# else: 0,0 fi); pickup fine.nib;
  248. numeric shaved_stem; shaved_stem=mfudged.stem;
  249. save stem; stem=shaved_stem;
  250. pos2(stem,0); x1=x2;
  251. y2-.5stem=-oo;
  252. if monospace: pos1(stem,0); lft x1l=hround(2.5u-.5stem); top y1=h;
  253. else:
  254.   x0=0; lft x2l=hround(2.5u-.5stem);
  255.   if classic_serif:
  256.     top y1=h; pos1(stem,0);
  257.     sloped_serif.l(1,2,a,1/3,jut,serif_drop);
  258.   else:
  259.     hook_in(0,a,1);
  260.   fi
  261. fi  % opening hook
  262. filldraw circ_stroke z2e--z1e;  % left stem
  263. x4+.5stem=hround(.5w+.5stem); ital_arch(2,3,4);  % left arch
  264. pos5(stem,0); y5=y2; x5=x4;
  265. filldraw circ_stroke z5e--z4e;  % middle stem
  266. x7+.5stem=hround(w-2.5u+.5stem);
  267. x8=x7-.25u; ital_arch(5,6,7);  % right arch
  268. if monospace: pos9(vair,90); x9=good.x .5[x8,w]; bot y9l=0; y8=1/3h;
  269.  pos8(stem,0); filldraw stroke z8e{-u,-x_height}...{right}z9e; % terminal
  270. else: x9=w; hook_out(8,b,9)(skewed); fi  % closing hook
  271. filldraw stroke z7e{down}..{-u,-x_height}z8e;  % right stem
  272. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  273. penlabels(0,a,1,2,3,4,5,6,7,8,9); endchar;
  274.  
  275. ecchar "Italic letter n";
  276. beginchar("n",10u#,x_height#,0);
  277. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  278. adjust_fit(0,0); pickup fine.nib;
  279. x0=0; x1=x2; pos2(stem,0); lft x2l=hround(2.5u-.5stem); y2-.5stem=-oo;
  280. if classic_serif:
  281.   top y1=h; pos1(stem,0);
  282.   sloped_serif.l(1,2,a,1/3,jut,serif_drop);
  283. else:
  284.   hook_in(0,a,1);  % opening hook
  285. fi
  286. filldraw circ_stroke z2e--z1e;  % left stem
  287. x4+.5stem=hround(w-2.5u+.5stem); x5=x4-.25u; ital_arch(2,3,4);  % arch
  288. x7=w; hook_out(5,6,7)(skewed);  % closing hook
  289. filldraw stroke z4e{down}..{-u,-x_height}z5e;  % right stem
  290. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  291. penlabels(0,a,1,2,3,4,5,6,7); endchar;
  292.  
  293. ecchar "Italic letter o";
  294. beginchar("o",9u#,x_height#,0);
  295. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  296. adjust_fit(0,0); pickup fine.nib;
  297. pos1(vair,90); pos2(curve,180); pos3(vair,270); pos4(curve,360);
  298. x1=x3=.5w; lft x2r=hround(1.5u-.5curve); x4=w-x2;
  299. top y1r=h+oo; y2=y4=.5[y1,y3]; bot y3r=-oo;
  300. filldraw stroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
  301.  & pulled_arc.e(3,4) & pulled_arc.e(4,1); % bowl
  302. math_fit(-.3x_height#*slant+.5curve#-u#,ic#); penlabels(1,2,3,4); endchar;
  303.  
  304. ecchar "Italic letter p";
  305. beginchar("p",9u#,x_height#,desc_depth#);
  306. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  307. adjust_fit(0,0); pickup fine.nib;
  308. x0=0; x2-.5stem=hround(2.5u-.5stem);
  309. if classic_serif:
  310.   pos2(stem,0);  % done previous by hook_in
  311.   y2=3/4x_height; % dito
  312. else:
  313.   hook_in(0,1,2);  % opening hook
  314. fi
  315.  
  316. pos4(hair,-180);
  317. pos5(vair,-90);
  318. pos6(curve,0);
  319. pos7(vair,90);
  320. x4=x2; rt x6r=hround(w-1.5u+.5curve); x5=x7=.5[x4,x6];
  321. bot y5r=-oo; top y7r=h+oo; y4=y6=.5[y5,y7];
  322.  
  323. if classic_serif:
  324.   x8=x2; pos8(stem,0); top y8=h;
  325.   sloped_serif.l(8,4,c,1/3,jut,serif_drop);
  326. fi
  327.  
  328. filldraw stroke super_arc.e(4,5) & pulled_arc.e(5,6)
  329.  & pulled_arc.e(6,7) & super_arc.e(7,4);  % bowl
  330. pickup tiny.nib; pos2'(stem,0); pos3(stem,0);
  331. z2=z2'; x3=x2; bot y3=-d;
  332. if classic_serif:
  333.  filldraw stroke z8e--z3e;  % stem
  334. else:
  335.  filldraw stroke z2'e--z3e;  % stem
  336. fi
  337. dish_serif(3,2',a,1/3,.75jut,b,1/3,jut);  % serif
  338. math_fit(-min(2/3x_height#*slant-.5hair#-.5u#,
  339.  2u#-.5stem#-desc_depth#*slant),ic#);
  340. penlabels(0,1,2,3,4,5,6,7 if classic_serif: ,8 fi); endchar;
  341.  
  342. ecchar "Italic letter q";
  343. beginchar("q",8u#,x_height#,desc_depth#);
  344. italcorr x_height#*slant+.5stem#-u#;
  345. adjust_fit(0,0); pickup fine.nib;
  346. pos0(hair,0); pos1(vair,90); pos2(curve,180); pos3(vair,270);
  347. x0=x4; x1=x3=.5[x0,x2]; lft x2r=hround(1.5u-.5curve);
  348. x4+.5stem=hround(w-1.5u+.5stem)+eps;
  349. top y1r=h+oo; bot y3r=-oo; y0=y2=.5[y1,y3];
  350. filldraw stroke super_arc.e(0,1) & pulled_arc.e(1,2)
  351.  & pulled_arc.e(2,3) & super_arc.e(3,0);  % bowl
  352. pickup tiny.nib; pos4(stem,0); pos5(stem,0);
  353. x4=x5; x6=x5r; top y6=h+oo; bot y4=-d;
  354. y5=ypart(((x4l,0)--(x4l,y6))intersectionpoint super_arc.r(0,1));
  355. filldraw z6{2(x5l-x6),y5-y6}...z5l---z4l--z4r--cycle;  % stem
  356. dish_serif(4,5,a,1/3,jut,b,1/3,jut);  % serif
  357. math_fit(-.3x_height#*slant+.5curve#-u#,ic#-1/3x_height#*slant);
  358. penlabels(0,1,2,3,4,5,6,7,8); endchar;
  359.  
  360. ecchar "Italic letter r";
  361. beginchar("r",5.5u#+max(1.75u#,flare#),x_height#,0);
  362. italcorr x_height#*slant;
  363. adjust_fit(if monospace:.25u#,.5u# else: 0,0 fi); pickup fine.nib;
  364. x0=0; x2=x3; pos3(stem,0); lft x3l=hround(2.5u-.5stem); y3-.5stem=-oo;
  365. if classic_serif:
  366.   pos2(stem,0);
  367.   y2=1/4x_height; % dito
  368.   x8=x2; pos8(stem,0); top y8=h;
  369.   sloped_serif.l(8,3,c,1/3,jut,serif_drop);
  370.   filldraw circ_stroke z8e--z3e;  % left stem
  371. else:
  372.   hook_in(0,1,2);  % opening hook
  373.   filldraw circ_stroke z3e--z2e;  % left stem
  374. fi
  375. pos3'(hair,180); z3'=z3; pos4(vair,90); pos5(hair,0); pos6(flare,0);
  376. x4=w-.5u-max(1.75u,flare); rt x5r=hround(r-.5u); top y4r=h+oo;
  377. filldraw stroke z3'e{up}...z4e{right};  % link
  378. y6+.5flare=vround(bot y4l-.03x_height); bulb(4,5,6);  % bulb
  379. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#-.5u#);
  380. penlabels(0,1,2,3,4,5,6); endchar;
  381.  
  382.  
  383. ecchar "Italic letter s";
  384. beginchar("s",5.25u#+max(1.75u#,flare#),x_height#,0);
  385. italcorr x_height#*slant-.5u#;
  386. adjust_fit(0,0); pickup fine.nib;
  387. numeric theta; theta=90-angle(40u,h); slope:=-h/40u;  % angle at middle
  388. pos2(vair,-90); pos0(max(fine.breadth,ess),theta); pos7(vair,-90);
  389. x2l=x0=x7=.5w; top y2l=h+oo; bot y7r=-oo;
  390. y0-.5ess=y7l+.55(y2r-y7l-ess);
  391. lft x3l=hround u-eps; rt x6r=hround(w-.5u)+eps;
  392. x3r-x3l=x6r-x6l=hround .5[vair,ess]-fine;
  393. ellipse_set(2l,3l,4l,0l); ellipse_set(2r,3r,4r,0r); y3=y3r;
  394. ellipse_set(7l,6l,5l,0l); ellipse_set(7r,6r,5r,0r); y6=y6r;
  395. interim superness:=more_super;
  396. filldraw stroke super_arc.e(2,3) & z3e{down}
  397.  ..z4e---z5e..z6e{down} & super_arc.e(6,7);  % main stroke
  398. pos1(hair,0); pos10(hround .75[hair,flare],0);
  399. pos2'(vair,90); z2'=z2;
  400. pos8(hair,-180); pos9(flare,-180);
  401. rt x10r=hround(w-u)+2eps; lft x9r=hround .5u-2eps; y10=.78h; y9=.25h;
  402. bulb(2',1,10); bulb(7,8,9);  % bulbs
  403. math_fit(0,ic#); penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  404.  
  405. ecchar "Italic letter t";
  406. beginchar("t",5.5u#,min(asc_height#,10/7x_height#),0);
  407. italcorr max(1/3x_height#*slant+.5hair#+.5u#,x_height#*slant-.25u#);
  408. adjust_fit(if monospace:u#,u# else:0,0 fi); pickup fine.nib;
  409. pos1(stem,0); lft x1l=hround(2u-.5stem); y1+.5stem=h+oo;
  410. x2=x1; x4=w; hook_out(2,3,4);  % closing hook
  411. if classic_serif:
  412.    filldraw stroke z1e--z2e;  % stem
  413. else:
  414.    filldraw circ_stroke z1e--z2e;  % stem
  415. fi
  416. pickup crisp.nib; pos5(bar,90); pos6(bar,90);
  417. lft x5=hround-.75u; rt x6=hround(w-.75u); top y5r=top y6r=x_height;
  418. filldraw stroke z5e--z6e;  % crossbar
  419. math_fit(1.25u#-x_height#*slant,ic#); penlabels(1,2,3,4,5,6); endchar;
  420.  
  421. ecchar "Italic letter u";
  422. beginchar("u",9.5u#,x_height#,0);
  423. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  424. adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
  425. if classic_serif:
  426.    x0=0; x2=x3; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  427.    pos2(stem,0);
  428.    top y2=h;
  429. else:
  430.   x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  431.   hook_in(0,1,2)(skewed);  % opening hook
  432. fi
  433. pos2'(stem,-180); z2'=z2;
  434. pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
  435. pos6(stem,0); rt x6r=hround(w-2.5u+.5stem);
  436. x5=x6=x7; x9=w; hook_out(7,8,9);  % closing hook
  437. y3=.7[y4,y5]; bot y4r=-oo; y5=.57h; y6+.5stem=h;
  438. if classic_serif:
  439.   filldraw stroke z2
  440.    ...super_arc.e(3,4)...{up}z5e; % left stem and arc
  441. else:
  442.   filldraw stroke z2'e{-u,-x_height}
  443.    ...super_arc.e(3,4)...{up}z5e; % left stem and arc
  444. fi
  445. filldraw circ_stroke z6e--z7e;  % right stem
  446. if classic_serif: sloped_serif.l(2,3,a,1/3,jut,serif_drop); fi
  447. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  448. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  449.  
  450.  
  451. ecchar "Italic letter v";
  452. beginchar("v",8u#,x_height#,0);
  453. italcorr x_height#*slant;
  454. adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
  455. x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  456. if classic_serif:
  457.   pos2(stem,0);
  458.   top y2=h;
  459. else:
  460.   hook_in(0,1,2)(skewed);  % opening hook
  461. fi
  462. pos2'(stem,-180); z2'=z2; pos4(vair,-90); pos5(hair,0);
  463. x4=.5w+u; rt x5r=hround(w-.5u); y3=.7[y4,y5]; bot y4r=-oo; y5=.57h;
  464. filldraw stroke z2'e{-u,-x_height}...super_arc.e(3,4)
  465.  ..tension atleast 1.05..{up}z5e; % left stem and arc
  466. v_bulb(5,6);  % closing bulb
  467. if classic_serif: sloped_serif.l(2,3,a,1/3,jut,serif_drop); fi
  468. math_fit(-2/3x_height#*slant+.5hair#+.5u#,2/3ic#);
  469. penlabels(0,1,2,3,4,5,6); endchar;
  470.  
  471. ecchar "Italic letter w";
  472. beginchar("w",12u#,x_height#,0);
  473. italcorr x_height#*slant;
  474. adjust_fit(if monospace:-1.5u#,-u# else: 0,0 fi);
  475. pickup fine.nib; interim superness:=more_super; begingroup
  476. forsuffixes $=hair,stem: shaved$:=mfudged$; save $; $=shaved$; endfor
  477. x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  478. if monospace: pos1(vair,90); x1=good.x .5[x0,x2]; top y1r=h; y2=2/3h;
  479.  pos2(stem,0); filldraw stroke z1e{right}...{-u,-x_height}z2e;
  480. else:
  481. if classic_serif:
  482.   pos2(stem,0);
  483.   top y2=h;
  484. else:
  485.   hook_in(0,1,2)(skewed);
  486. fi
  487. fi  % opening hook
  488. pos2'(stem,-180); z2'=z2;
  489. pos4(vair,-90); pos5(hair,0);
  490. x4=.6[x2,x5]; x5=x6=x7; pos6(stem,-180); pos7(stem,-180);
  491. y3=.7[y4,y5]; bot y4r=-oo; y5=.57h;
  492. rt x6l=hround(rt x6l+.5w+.75u-x6); y6+.5stem=h; y7=y3;
  493. pos8(vair,-90); pos9(hair,0);
  494. x8=w-2.75u; rt x9r=hround(w-.5u); bot y8r=-oo; y9=y5;
  495. if classic_serif: sloped_serif.l(2,3,a,1/3,jut,serif_drop); fi
  496. filldraw stroke z2'e{-u,-x_height}
  497.  ...super_arc.e(3,4)...{up}z5e; % left stem and arc
  498. filldraw circ_stroke z6e..super_arc.e(7,8)...{up}z9e;  % middle stem and arc
  499. v_bulb(9,10);  % closing bulb
  500. endgroup; math_fit(-2/3x_height#*slant+.5hair#+.5u#,3/4ic#);
  501. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  502.  
  503. ecchar "Italic letter x";
  504. beginchar("x",6.5u#+max(1.5u#,flare#),x_height#,0);
  505. italcorr max(1/3x_height#*slant+.5hair#+.5u#,x_height#*slant+.25u#);
  506. adjust_fit(0,0); pickup fine.nib;
  507. pos0(hair,180); pos1(vair,90); pos2(stem,0);
  508. pos3(stem,-180); pos4(vair,-90); pos5(hair,0);
  509. y0=y2=2/3h; y3=y5=1/3h; top y1r=h+oo; bot y4r=-oo;
  510. rt x2r=hround(.5w+.5stem-eps); x2=x3;
  511. x0-.5hair=hround-.5hair; x5+.5hair=hround(w+.5hair-eps);
  512. x1=.5[x0,x2]; x4=.5[x3,x5];
  513. filldraw stroke z0e{up}...pulled_arc.e(1,2); % opening hook
  514. filldraw z2l--z3r--z3l--z2r--cycle;  % stem
  515. filldraw stroke pulled_arc.e(3,4)...{up}z5e;  % closing hook
  516. pos3'(hair,180); pos6(hair,180); pos7(vair,90);
  517. pos8(hair,0); pos9(flare,0);
  518. x3'l=x6l=x3l; y3'=y3; y6=3/4h; x7=.5[x8,x2]; top y7r=h+oo;
  519. rt x8r=hround(w-.25u); y8+.5flare=vround(bot y7l-.03x_height);
  520. filldraw stroke z3'e---z6e...{right}z7e; bulb(7,8,9);  % upper link and bulb
  521. pos2'(hair,0); pos16(hair,0); pos17(vair,-90);
  522. pos18(hair,-180); pos19(flare,-180);
  523. x2'l=x16l=x2l; y2'=y2; y16=1/4h; x17=.5[x18,x3]; bot y17r=-oo;
  524. lft x18r=hround.25u; y18-.5flare=vround(top y17l+.03x_height);
  525. filldraw stroke z2'e---z16e...{left}z17e; bulb(17,18,19); % lower link and bulb
  526. math_fit(0,ic#); penlabels(0,1,2,3,4,5,6,7,8,9,16,17,18,19); endchar;
  527.  
  528. ecchar "Italic letter y";
  529. beginchar("y",8.5u#,x_height#,desc_depth#);
  530. italcorr x_height#*slant+.5stem#-u#;
  531. adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
  532. x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  533. if classic_serif:
  534.   pos2(stem,0);
  535.   top y2=h;
  536. else:
  537.   hook_in(0,1,2)(skewed);  % opening hook
  538. fi
  539. pos2'(stem,-180); z2'=z2;
  540. pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
  541. pos6(stem,0); rt x6r=hround(w-1.5u+.5stem);
  542. pos7(stem,0); pos8(vair,-90);
  543. y3=.7[y4,y5]; bot y4r=-oo; y5=.57h; y6+.5stem=h;
  544. y7=0; bot y8r=-d-oo; x5=x6=x7; x8=.5w;
  545. pos9(hair,-180); pos10(flare,-180); y9=-.5d;
  546. lft x9r=hround(2.75u-.5flare); bulb(8,9,10);  % bulb
  547. filldraw stroke z2'e{-u,-x_height}
  548.  ...super_arc.e(3,4)...{up}z5e; % left stem and arc
  549. filldraw circ_stroke z6e---z7e...{left}z8e;  % right stem and link
  550. if classic_serif: sloped_serif.l(2,3,a,1/3,jut,serif_drop); fi
  551. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#-1/3x_height#*slant);
  552. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  553.  
  554. ecchar "Italic letter z";
  555. beginchar("z",5.5u#+max(1.5u#,stem#),x_height#,0);
  556. italcorr x_height#*slant+.5hair#;
  557. adjust_fit(if monospace:.5u#,.5u# else: 0,0 fi); pickup fine.nib;
  558. pos1(hair,0); pos2(stem,-90); pos3(vair,-90); pos4(hair,0);
  559. lft x1l=hround(u-.5hair); x2=2.5u; x3=w-2u; rt x4r=hround(w-.5u);
  560. top y1=.78h; top y2l=top y4=h+oo; y3=.825h;
  561. pos5(hair,0); pos6(vair,-90); pos7(stem,-90); pos8(hair,0);
  562. x5=x1; x6=2.5u; x7=w-2u; x8+.5hair=hround(w+.5hair-eps);
  563. bot y5=bot y7r=-oo; y6=.175h; bot y8=.31h;
  564. pair p; p=(z4-z5) yscaled 2;
  565. filldraw stroke z1e{up}...z2e{right}..z3e{right}...{p}z4e;  % upper bar
  566. filldraw stroke z5e{p}...z6e{right}..{right}z7e...{up}z8e;  % lower bar
  567. filldraw stroke z5e{p}..{p}z4e;  % diagonal
  568. math_fit(0,1/3x_height#*slant+.5hair#+.5u#);
  569. penlabels(1,2,3,4,5,6,7,8); endchar;
  570.  
  571. endinput;
  572.